class REAPER_DisableDestructionHelperEntityClass : GenericEntityClass {}

class REAPER_DisableDestructionHelperEntity : GenericEntity
{
	[Attribute("10", uiwidget: UIWidgets.Auto, desc: "REAPER: Search radius for Buldings", category: "REAPER Disable Building Destruction Helper")]
	protected int m_SearchForBuildingsRadius;
	
	[Attribute("1", uiwidget: UIWidgets.Auto, desc: "REAPER: Only disable the first building, found in query", category: "REAPER Disable Building Destruction Helper")]
	protected bool m_OnlyDisableTheFirstBuilding;
	
	//------------------------------------------------------------------------------------------
	
	override event protected void EOnActivate(IEntity owner)
	{
		if(!Replication.IsServer()) return;
		
		BaseWorld world = GetGame().GetWorld();	
		world.QueryEntitiesBySphere(owner.GetOrigin(), m_SearchForBuildingsRadius, REAPER_GetNearBuildingsQuery, null, EQueryEntitiesFlags.STATIC);	
	}
	
	//------------------------------------------------------------------------------------------------
	
	protected bool REAPER_GetNearBuildingsQuery(IEntity ent)
	{		
		SCR_DestructibleBuildingEntity buildingEnt = SCR_DestructibleBuildingEntity.Cast(ent); 	
		if(buildingEnt) {
			
			SCR_DestructibleBuildingComponent destructComp = SCR_DestructibleBuildingComponent.Cast(buildingEnt.FindComponent(SCR_DestructibleBuildingComponent)); 
			if(destructComp) {
				
				destructComp.EnableDamageHandling(false); 
				if(m_OnlyDisableTheFirstBuilding) return false;
			}
		}
		// Keep looking
		return true;
	}	
}