[] spawn {
	/* ----------------------------------------------------------------------------
		Setup
	---------------------------------------------------------------------------- */
	#define INITIAL_SPAWN_DISTANCE 550
	#define DYNAMIC_SIMULATION_DISTANCE 500
	#define ENEMY_UNIT_TYPE "O_Soldier_F"
	#define SLEEP_TIME 0.1

	player setDir 0;
	player allowDamage false;
	player setCaptive true;
	player triggerDynamicSimulation true;

	enableDynamicSimulationSystem true;
	"IsMoving" setDynamicSimulationDistanceCoef 1;
	"Group" setDynamicSimulationDistance DYNAMIC_SIMULATION_DISTANCE;

	private _enemySpawnPosition = player getPos [INITIAL_SPAWN_DISTANCE,0];
	private _enemyGroup = createGroup opfor;
	private _enemyUnit = _enemyGroup createUnit [ENEMY_UNIT_TYPE,_enemySpawnPosition,[],0,"NONE"];


	/* ----------------------------------------------------------------------------
		Test
	---------------------------------------------------------------------------- */
	private _wasSimulatedBeforeDynamicSimulationWasEnabled = simulationEnabled _enemyUnit;
	sleep SLEEP_TIME;

	_enemyGroup enableDynamicSimulation true;
	sleep SLEEP_TIME;

	private _wasSimulatedAfterDynamicSimulationWasEnabled = simulationEnabled _enemyUnit;
	sleep SLEEP_TIME;

	player setPosASL ((getPosASL _enemyUnit) vectorDiff [0,5,0]);
	player setDir 0;
	sleep SLEEP_TIME;

	private _wasSimulatedAfterPlayerWasTeleportedToEnemy = simulationEnabled _enemyUnit;
	sleep SLEEP_TIME;

	player setPosASL (AGLToASL (_enemyUnit getPos [INITIAL_SPAWN_DISTANCE,180]));
	player setDir 0;
	sleep SLEEP_TIME;

	private _wasSimulatedAfterPlayerWasTeleportedAwayFromEnemy = simulationEnabled _enemyUnit;
	sleep SLEEP_TIME;

	_enemyUnit setPosASL ((getPosASL player) vectorAdd [0,5,0]);
	sleep SLEEP_TIME;

	private _wasSimulatedAfterBeingTeleportedToPlayer = simulationEnabled _enemyUnit;
	deleteVehicle _enemyUnit;
	deleteGroup _enemyGroup;
	enableDynamicSimulationSystem false;


	/* ----------------------------------------------------------------------------
		Output
	---------------------------------------------------------------------------- */
	if !(_wasSimulatedBeforeDynamicSimulationWasEnabled) exitWith {
		hint "--FAILED: Expected simulation of enemy unit BEFORE enabling Dynamic Simulation to be TRUE";
	};

	if (_wasSimulatedAfterDynamicSimulationWasEnabled) exitWith {
		hint "--FAILED: Expected simulation of enemy unit AFTER enabling Dynamic Simulation to be FALSE";
	};

	if !(_wasSimulatedAfterPlayerWasTeleportedToEnemy) exitWith {
		hint "--FAILED: Expected simulation of enemy unit after player was teleported CLOSE to the enemy unit, to be TRUE";
	};

	if (_wasSimulatedAfterPlayerWasTeleportedAwayFromEnemy) exitWith {
		hint "--FAILED: Expected simulation of enemy unit after player was teleported AWAY from the enemy unit, to be FALSE";
	};

	if !(_wasSimulatedAfterBeingTeleportedToPlayer) exitWith {
		hint "--FAILED: Expected simulation of enemy unit after being teleported to player, to be TRUE";
	};

	hint "Test Passed!";
};