//if the player isn't in a helicopter then we don't run this
if(vehicle player iskindof  "Helicopter") then
{
_heli = vehicle player;
if(isNil "button_clicked") then {button_clicked = 0;}; //keeps our key from constantly having an effect - that is, press it once and it won't do anything again until released and pressed again

_controlpos = worldToScreen (_heli modelToWorldVisual [0,2,0]);

if(count _controlpos < 2) then {_controlpos = [-100,-100];}; //if the point is outside of our FOV then set it to something ridiculous
_hinttext = "No Action"; //basic hint to indicate what we're looking at

player sidechat format ["%1",_controlpos]; //debugging - shows position of a control on screen coordinates; the closer to 0.5,0.5, the closer it is to the center of the screen

if(_controlpos distance [0.5,0.5] < 0.025) then {_hinttext = "Toggle Engine";}; //change hint to engine on

if(!(_hinttext == "")) then {hintsilent format ["%1",_hinttext];}; //set our hint text

if(_hinttext == "No Action") exitwith {}; //if no action available then we don't need to do anything so quit

//check to see if our action is within the right parameters and that the key has been pressed, then do something
if(inputaction "User20" > 0.1 && button_clicked == 0 && _controlpos distance [0.5,0.5] < 0.01) then
{
	if(isengineon _heli) then
	{
		player action ["EngineOff", _heli];
	} else {
		player action ["EngineOn", _heli];
	};
button_clicked = 1;
};

//clear our key press if it's not being pressed
if(inputaction "User20" < 0.5) then
{
button_clicked = 0;
};
};

my_clickaction = compile preprocessFileLineNumbers "pfh_click.sqf";  ["my_clickid", "onEachFrame", "my_clickaction"] call BIS_fnc_addStackedEventHandler;