modded class PlayerBase
{
	bool m_ConditionIsMet = true;

	override void EEKilled( Object killer )
	{
		Print( string.Format( "EEKilled - Killer: %1 Is Alive: %2 Is Damage Destroyed: %3", killer.GetType(), IsAlive(), IsDamageDestroyed() )  );
		
		if ( m_ConditionIsMet )
		{
			return;
		}

		super.EEKilled( killer );
	}

	override void EEHitBy( TotalDamageResult damageResult, int damageType, EntityAI source, int component, string dmgZone, string ammo, vector modelPos )
	{
		Print( string.Format( "EEHitBy - Source: %1 Zone: %2 Is Alive: %3 Is Damage Destroyed: %4", source.GetType(), dmgZone, IsAlive(), IsDamageDestroyed() )  );

		if ( m_ConditionIsMet )
		{
			RestoreFromTotalDamageResult( damageResult );
			return;
		}

		super.EEHitBy( damageResult, damageType, source, component, dmgZone, ammo, modelPos );
	}

	void RestoreFromTotalDamageResult( notnull TotalDamageResult damageResult )
	{
		ref array<string> zones = new array<string>;

		GetDamageZones( zones );
		
		AddHealth( "GlobalHealth", "Health", damageResult.GetDamage( "GlobalHealth", "Health" ) );

		if ( IsMan() )
		{
			if ( GetMaxHealth( "GlobalHealth", "Blood" ) > 0 )
			{
				AddHealth( "GlobalHealth", "Blood", damageResult.GetDamage( "GlobalHealth", "Blood" ) );
			}

			if ( GetMaxHealth( "GlobalHealth", "Shock" ) > 0 )
			{
				AddHealth( "GlobalHealth", "Shock", damageResult.GetDamage( "GlobalHealth", "Shock" ) );
			}
		}
		
		foreach ( string zone : zones )
		{
			AddHealth( zone, "Health", damageResult.GetDamage( zone, "Health" ) );
			
			if ( IsMan() )
			{
				if ( GetMaxHealth( zone, "Blood" ) > 0 )
				{
					AddHealth( zone, "Blood", damageResult.GetDamage( zone, "Blood" ) );
				}

				if ( GetMaxHealth( zone, "Shock" ) > 0 )
				{
					AddHealth( zone, "Shock", damageResult.GetDamage( zone, "Shock" ) );
				}
			}
		}
	}
}